大连机车厂官网:如何用汇编计算延时？

我给你一个微秒的延吧，不过不要问我为什么，说实话我是从BC里TD出来再修改而成的（只是从逻辑上进行优化）：;-----------------------------------------------------------------
;
; Delay.asm
;
; Wait for specified period.
;
;
; Run Time Library for Future Assember
; Revision: 1.02
; Author: Chen Wen-yao
; Date: 2004.10.15
;
; Copyright (c) 1999, 2001 by Futuresoft
; All Rights Reserved.
;
;-----------------------------------------------------------------
include system.inc

MULTIPIER = 1193d*2d

.CODE
assume cs:@Code

;void pascal Delay(unsigned Milliseconds);

public @@Delay

@@Delay proc near
push bp
mov bp,sp
;
push di
push si
;stop=di:si,cur=dx,prev=cx
call __ReadTimer
mov cx,dx
mov ax,[bp+04h]
mov dx,MULTIPIER
mul dx
mov di,dx
mov si,ax
add si,cx
adc di,00h
@begin:
call __ReadTimer
or di,di
jnz @continue
cmp si,dx
ja @continue
@return:
pop si
pop di
pop bp
ret 02h
@continue:
cmp dx,cx
jnb @skip
or di,di
jz @return
dec di
@skip:
mov cx,dx
jmp @begin
@@Delay endp

__nothing proc ;nothing but waste time
ret
__nothing endp

__ReadTimer proc near
;
pushf
cli

mov al,00h
out 43h,al

call __nothing

in al,40h
mov dl,al

call __nothing

in al,40h
mov dh,al

not dx
popf
;
ret
__ReadTimer endp

end